PROGRAM

  ! Aufruf: RUN('so_tapi.exe "Nummer"')

  MAP
    MODULE('ctapi32.lib')
      TapiRequestMakeCall(*CSTRING,*CSTRING,*CSTRING,Long),LONG,RAW,PASCAL
    END
    Main
  END

  CODE
  Main
  RETURN

!-----------------------------------------------------------------------------------------------
Main PROCEDURE

bI              BYTE
bN              BYTE
cDial           STRING(30)
csTapiNumber    CSTRING(30)
csTapiShowName  CSTRING(120)
csTapiAppName   CSTRING(120)

cNr             STRING(255)

  CODE
  ! Aufrufparamater einlesen
  cNr = COMMAND()

  ! Nummer lesen
  LOOP bI = 1 TO LEN(CLIP(cNr))
    IF INSTRING(cNr[bI],'0123456789',1,1) ! es werden nur Ziffern gelesen
      bN += 1
      cDial[bN] = cNr[bI]
    END
  END
  IF CLIP(cDial) = ''  ! keine Nummer
    RETURN
  END

  csTapiNumber = CLIP(cDial)
  ! Windows-Wählhilfe starten
  IF NOT TapiRequestMakeCall(csTapiNumber,csTapiAppName,csTapiShowName,0) = 0
    MESSAGE('Es ist ein Fehler aufgetreten.<10>Versuchen Sie es erneut<10>oder wählen Sie Nummer von Hand.',|
            ,ICON:Exclamation)
  END
  RETURN