Set objServiceManager = WScript.CreateObject("com.sun.star.ServiceManager")
Set objConnection = objServiceManager.CreateInstance("com.sun.star.sdb.DatabaseContext")
Set objDataSource = objConnection.createInstance()
objDataSource.url = "sdbc:calc:c:\sloffice\schueler.ods"
Set objConnection = objDataSource.getConnection("", "")

'  Erstellt ein neues MailMerge-Objekt
Set objMailManager = objServiceManager.CreateInstance("com.sun.star.text.MailMerge")

' Einstellungen des neuen Mailmerge-Objekts
' Name der Datenbank
objMailManager.DataSourceName = "slo"

' aktuelle Verbindung zur Datenbank
objMailManager.ActiveConnection = objConnection

' Dateiname des Hauptdokuments wieder mit Slashs (/) z.B.: c:/sloffice/serienbriefe/anmahnung.odt (kann auch eine Formatvorlage (.ott)  sein)
objMailManager.DocumentURL = "file:///c:/sloffice/serienbriefe/anmahnung.odt"

' Art der  Datenquelle
objMailManager.CommandType = 0 'Die Datenquelle ist 0 = Tabelle, 1 = Abfrage, 2 = SQL-Abfrage

' Name der Tabelle
' ist immer die erste und einzige Tabelle in der Datenbank
' es könnte hier auch "Tabelle1" stehen
' ob das aber auch in englischen Versionen von OpenOffice gilt, wissen wir nicht (wir glauben aber eher nicht)
' deshalb lesen wir den Namen der ersten Tabelle aus der Datenbank
objMailManager.Command = objConnection.getTables().getByIndex(0).name ' erste Tabelle in der Datenbank

' Art der Ausgabe 1=zum Drucker, 2=in Datei
objMailManager.OutputType = 2

' Dateipfad der Ausgabedatei wieder mit Slashs z.B.:  c:/temp/sloffice/ (abschließenden Slash beachten)
objMailManager.OutputUrl = "file:///c:/temp/sloffice/"

' Art der Ausgabedatei True = ein Dokument erstellen, False = einzelne Dokumente für jeden Datensatz in der Datenquelle erstellen
objMailManager.SaveAsSingleFile = True

' MailMerge ausführen
objMailManager.Execute Array()